Creating Image Objects

To create an image object, supply an array of pixel values to the IDLgrImage::Init method. If the image has more than one channel, be sure to set the INTERLEAVE property of the image object to the appropriate value. (See RGB Image Interleaving (Using IDL) for details and an example showing how to determine the interleaving within an image array.) See "IDLgrImage" (IDL Reference Guide) for details on object properties and methods.

Note
IDLgrImage does not treat NaN data as missing. If the image data includes NaNs, it is recommended that the BYTSCL function be used to appropriately handle those values. For example:
   oImage->SetProperty, DATA = BYTSCL(myData, /NaN, MIN=0,
      MAX=255)

In Object Graphics, binary, grayscale, indexed, and RGB images are contained in image objects. For display, the image object is contained within an object hierarchy, which includes a model object and a view object. The view object is then drawn to a window object. Some types of images must be scaled with the BYTSCL function prior to display.

For more information, refer to the following examples:

Displaying Binary Images with Object Graphics

Binary images are composed of pixels having one of two values, usually zero or one. With most color tables, pixels having values of zero and one are displayed with almost the same color, such as with the default grayscale color table. Thus, a binary image is usually scaled to display the zeros as black and the ones as white.

The following example imports a binary image of the world from the continent_mask.dat binary file. In this image, the oceans are zeros (black) and the continents are ones (white). This type of image can be used to mask out (omit) data over the oceans. The image contains byte data values and is 360 pixels by 360 pixels.

Example Code
See displaybinaryimage_object.pro in the examples/doc/objects subdirectory of the IDL installation directory for code that duplicates this example. Run the example procedure by entering displaybinaryimage at the IDL command prompt or view the file in an IDL Editor window by entering .EDIT displaybinaryimage.pro.

  1. Determine the path to the continent_mask.dat file:
    2. file = FILEPATH('continent_mask.dat', $ 
   SUBDIRECTORY = ['examples', 'data'])
  2. Initialize the image size parameter:
    3. imageSize = [360, 360]
  3. Use READ_BINARY to import the image from the file:
    4. image = READ_BINARY(file, DATA_DIMS = imageSize)
  4. Initialize the display objects:
    5. oWindow = OBJ_NEW('IDLgrWindow', RETAIN = 2, $ 
   DIMENSIONS = imageSize, $ 
   TITLE = 'A Binary Image, Not Scaled') 
oView = OBJ_NEW('IDLgrView', $ 
   VIEWPLANE_RECT = [0., 0., imageSize]) 
oModel = OBJ_NEW('IDLgrModel')
  5. Initialize the image object:
    6. oImage = OBJ_NEW('IDLgrImage', image)
  6. Add the image object to the model, which is added to the view, then display the view in the window:
    7. oModel -> Add, oImage 
oView -> Add, oModel 
oWindow -> Draw, oView 
 
    The resulting window should be all black (blank). The binary image contains zeros and ones, which are almost the same color (black). A binary image should be scaled prior to displaying in order to show the ones as white.
  7. Initialize another window:
    8. oWindow = OBJ_NEW('IDLgrWindow', RETAIN = 2, $ 
   DIMENSIONS = imageSize, $ 
   TITLE = 'A Binary Image, Scaled')
  8. Update the image object with a scaled version of the image:
    9. oImage -> SetProperty, DATA = BYTSCL(image)
  9. Display the view in the window:
    10. oWindow -> Draw, oView 
 
    The following figure shows the results of scaling this display.
     
    

    

    
   
    Figure 4-1: Binary Image in Object Graphics
    
  
         
    

    

    imgdisp06.gif
  10. Clean up the object references. When working with objects always remember to clean up any object references with the OBJ_DESTROY routine. Since the view contains all the other objects, except for the window (which is destroyed by the user), you only need to use OBJ_DESTROY on the view object.
    11. OBJ_DESTROY, oView

Displaying Grayscale Images with Object Graphics

Since grayscale images are composed of pixels of varying intensities, they are best displayed with color tables that progress linearly from black to white. IDL provides several such pre-defined color tables, but the default grayscale color table is generally suitable.

The following example imports a grayscale image from the convec.dat binary file. This grayscale image shows the convection of the Earth's mantle. The image contains byte data values and is 248 pixels by 248 pixels. Since the data type is byte, this image does not need to be scaled before display. If the data was of any type other than byte and the data values were not within the range of 0 up to 255, the display would need to scale the image in order to show its intensities. Complete the following steps for a detailed description of the process.

Example Code
See displaygrayscaleimage_object.pro in the examples/doc/objects subdirectory of the IDL installation directory for code that duplicates this example. Run the example procedure by entering displaygrayscaleimage at the IDL command prompt or view the file in an IDL Editor window by entering .EDIT displaygrayscaleimage.pro.

  1. Determine the path to the convec.dat file:
    2. file = FILEPATH('convec.dat', $ 
   SUBDIRECTORY = ['examples', 'data'])
  2. Initialize the image size parameter:
    3. imageSize = [248, 248]
  3. Using READ_BINARY, import the image from the file:
    4. image = READ_BINARY(file, DATA_DIMS = imageSize)
  4. Initialize the display objects:
    5. oWindow = OBJ_NEW('IDLgrWindow', RETAIN = 2, $ 
   DIMENSIONS = imageSize, $ 
   TITLE = 'A Grayscale Image') 
oView = OBJ_NEW('IDLgrView', $ 
   VIEWPLANE_RECT = [0., 0., imageSize]) 
oModel = OBJ_NEW('IDLgrModel')
  5. Initialize the image object:
    6. oImage = OBJ_NEW('IDLgrImage', image, /GREYSCALE)
  6. Add the image object to the model, which is added to the view, then display the view in the window:
    7. oModel -> Add, oImage 
oView -> Add, oModel 
oWindow -> Draw, oView 
 
    The following figure shows the resulting grayscale image display.
     
    

    

    
   
    Figure 4-2: Grayscale Image in Object Graphics
    
  
         
    

    

    imgdisp07.gif
  7. Clean up the object references. When working with objects always remember to clean up any object references with the OBJ_DESTROY routine. Since the view contains all the other objects, except for the window (which is destroyed by the user), you only need to use OBJ_DESTROY on the view object.
    8. OBJ_DESTROY, oView